Go Back   Steam Users' Forums > Steam Game Discussions > Q - S > Star Wars collection > Knights of the Old Republic Series

Reply
 
Thread Tools Display Modes
Old 03-05-2012, 07:31 PM   #16
TarkinMX
 
Join Date: Jan 2012
Reputation: 0
Posts: 2
After last patch, this got messed up for me. When I started it steam would show me in non-steam game when the launcher was running but then it would drop it after pressing play and the game starting up, still had the overlay though. I downloaded the one from Chapso's repo link and compiled that one and it's working correctly again.
TarkinMX is offline   Reply With Quote
Old 04-06-2012, 07:37 AM   #17
lxracer
 
Join Date: Nov 2008
Reputation: 0
Posts: 1
I just followed the instructions and everything seems to have worked great. I messed around with the character creation and I did not notice any issues there. I selected my character and entered the game without issue, too.

Thanks OP!
lxracer is offline   Reply With Quote
Old 04-09-2012, 03:52 AM   #18
Ashton2571
 
Join Date: Sep 2009
Reputation: 0
Posts: 8
PLEASE HELP
---
I followed the steps exactly but when I start her up there are no servers showing. I have no idea what is happening please help because the overlay works but the game doesn't.

The game works find without the overlay version but I really really want this steam overlay to work!

Here is a screenshot of the issue. http://steamcommunity.com/id/2571/sc...930?tab=public

Last edited by Ashton2571: 04-09-2012 at 04:51 PM. Reason: Added information
Ashton2571 is offline   Reply With Quote
Old 04-15-2012, 12:23 AM   #19
Lann094
 
 
 
Join Date: Jan 2009
Reputation: 1
Posts: 67
I followed his other method of launching (with some tweaks of my own to fix it launching the wrong game).

In this method you make a file called SWTOR_SteamLaunch.vbs (Copy the code below to notepad, save as that file) in the same directory as launcher.exe and edit your SWtOR Steam shortcut as such:
Target: "C:\Windows\system32\cscript.exe" "<SWtOR directory>\SWtOR_SteamLaunch.vbs"
Start in: "C:\Windows\system32"

Code:
' if nothing was passed in, we are starting from scratch, so start the launcher
If WScript.Arguments.length = 0 Then
	swtorHome = WScript.ScriptFullName
	swtorHome = Left(swtorHome, InStr(swtorHome, WScript.ScriptName)-1)
	
	'run the launcher
	Set objShell = WScript.CreateObject("Shell.Application")
	objShell.ShellExecute "D:\Games\Star Wars The Old Republic\launcher.exe", "", swtorHome
	
	' create the file that the elevated script will copy swtor's path and commandline to
	set fso = CreateObject("Scripting.FileSystemObject")
	set tempfolder = fso.GetSpecialFolder(2)
	tempname = tempfolder & "\" & "SWtOR_SteamLaunch.tmp"
	set tempfile = fso.CreateTextFile(tempname)
	tempfile.close()

	'run this script but signal that it needs to elevate by giving it the tempfile name as an argument
	Set objShell = CreateObject("Shell.Application")
	objShell.ShellExecute "cscript.exe", Chr(34) & WScript.ScriptFullName & Chr(34) & " " & tempname, "", "runas", 1

	WScript.Echo "Waiting for other script to finish..."
	' check every second if the temporary file has been updated with the commandline info
	Do While True
		'check the filesize of the tempfile
		set tempfile = fso.GetFile(tempname)
		If tempfile.Size > 0 Then Exit Do
		WScript.Sleep 1000
	Loop
	
	swtorExecutablePath = swtorHome + "swtor\retailclient"
	set tempfile = fso.OpenTextFile(tempname)
	swtorCommandLine = tempfile.ReadLine
	tempfile.close()
	
	Set objShell = CreateObject("Shell.Application")
	objShell.ShellExecute "swtor.exe", swtorCommandLine, swtorExecutablePath

	fso.DeleteFile tempname
	WScript.Quit
Else
	' we are elevated now	
	WScript.Echo "Waiting for launcher to start swtor..."
	
	'Get Windows Manager object 
	Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\.\root\cimv2")

	' check every second for swtor.exe that was launched by swtor's launcher
	While True
	
		'Get info on processes named "swtor.exe"
		Set swtorInstanceList = objWMIService.ExecQuery _ 
		("Select * from Win32_Process Where Name =""swtor.exe""")
		
		for Each swtorInstance in swtorInstanceList
			cmdline = swtorInstance.CommandLine
	
			'look for something only our swtor will have in it's commandline arguments
			If InStr(cmdline, "username") > 0 Then
				'we found the swtor.exe we care about
				swtorInstance.Terminate()
				
				'remove the exe path and name from the cmdline
				position = InStr(1, cmdline, """ ") + 1
				cleanCmdLine = Right(cmdline, Len(cmdline) - position)
				
				tempname = WScript.Arguments(0)
				set fso = CreateObject("Scripting.FileSystemObject")
				set tempfile = fso.OpenTextFile(tempname, 2)
				tempfile.WriteLine(cleanCmdLine)
				tempfile.close()

				WScript.Quit
			End If
		Next	
		
		WScript.Sleep 1000
	Wend
End If
Continues to work for me in 1.2 on Win7 x64.
Great thanks to the guy that came up with this.

To anyone with better vb knowledge than I, could this be modified to work with any MMO that uses a launcher?

EDIT: Just realised my tweaks only will only work if you have the game installed to D:\Games\Star Wars The Old Republic\ so wherever you see that, just replace it with where your game is installed.

Last edited by Lann094: 04-15-2012 at 12:30 AM. Reason: Clarification
Lann094 is offline   Reply With Quote
Old 04-15-2012, 09:21 AM   #20
Bardock-Sama
 
Join Date: Feb 2010
Reputation: 0
Posts: 1
Pure win!

Very awesome, worked like a charm for me the first time =D

Big thanks to OP!
Bardock-Sama is offline   Reply With Quote
Old 04-21-2012, 08:18 AM   #21
Xavior
 
Join Date: Mar 2011
Reputation: 0
Posts: 1
The problem is your are supposed to save it as swtorsteam.txt

It looks like the original post was edited slightly. By looking at the command here:
Quote:
string pipeName = "swtorsteam"
We can see it has to reference swtorsteam, i.e. itself, for it to work properly. This is how it worked originally for me and continues to work.
Xavior is offline   Reply With Quote
Old 07-02-2012, 12:02 AM   #22
Sabster
 
 
 
Join Date: May 2007
Reputation: 17
Posts: 509
Semi-off topic: Has anyone gotten this script to work with Diablo III?

And yes, I know you can run diablo III with the launch command line; but I'd really like to do what this does - with D3's launcher... (I'm being difficult...)
Sabster is offline   Reply With Quote
Reply

Go Back   Steam Users' Forums > Steam Game Discussions > Q - S > Star Wars collection > Knights of the Old Republic Series


Thread Tools
Display Modes

Posting Rules
You may not post new threads
You may not post replies
You may not post attachments
You may not edit your posts

BB code is On
Smilies are On
[IMG] code is Off
HTML code is Off



All times are GMT -7. The time now is 02:43 AM.


Powered by vBulletin® Version 3.8.7
Copyright ©2000 - 2014, vBulletin Solutions, Inc.
Site Content Copyright Valve Corporation 1998-2014, All Rights Reserved.